Banking Supervision

% base case: if a company X owns Y with shares Q then there is a direct
% controlled_share relationship from X to Y with share Q
controlled_shares(X,Y,Y,Q) <- own(X,Y,Q), X<>Y.

% recursive case: if a company X controls Y with shares K
% and the company Y owns Z with share Q, then there is an indirect
% controlled_share relationship from X to Y via Z with share Q
controlled_shares(X,Z,Y,Q) <- control(X,Y), own(Y,Z,Q), X<>Z, Z<>Y, X<>Y.

% if X has controlled_shares of Y, via any company Z with shares Q, then the total
% controlled share are computed with an aggregation msum, that groups
% by X and Z and aggregates the sum of Q
total_controlled_shares(X,Y,S) <- controlled_shares(X,Y,Z,Q), S=msum(Q).

% if the total controlled shares Q of Y by X is greater than 0.5, then X
% controls Y with shares Q.
control(X,Y) <- total_controlled_shares(X,Y,Q), Q>0.5.

@output("control").

own("Alpha Treasury","Phoenix Vault",0.7).
own("Alpha Treasury","Initech",0.4).
own("Phoenix Vault","Initech",0.1).
own("Phoenix Vault","Royal Crown Bank",0.6).
own("Royal Crown Bank","Initech",0.1).
own("Royal Crown Bank","Goldward Bank",0.3).
own("Goldleaf Bank","Acme Corp",0.4).
own("Initech","Acme Corp",0.4).
own("Initech","Soylent Corp",0.99).
own("Soylent Corp","Goldward Bank",0.3).

control("Alpha Treasury","Phoenix Vault").
control("Alpha Treasury","Royal Crown Bank").
control("Alpha Treasury","Initech").
control("Alpha Treasury","Soylent Corp").
control("Alpha Treasury","Godward Bank").
control("Phoenix Vault","Royal Crown Bank").
control("Initech","Soylent Corp").
control("Initech","Acme Corp").

% input company graph, described as ownership edges
% the company A owns 0.2% of shares of the company B
own("A", "B", 0.2).
% the company B owns 0.8% of shares of the company A
own("B", "A", 0.8).
own("B", "C", 0.2).
own("C", "D", 0.6).
own("D", "A", 0.9).
own("A", "C", 0.2).

% if the company X owns a percentage W of shares of Y and we add in a set
% the visited node X and the visited node Y, then there is a closeLinkPaths of X
% over Y with shares W and we bring the list of visited nodes P.
closeLinkPaths(X,Y,W,P) <- own(X,Y,W), P={}|X|Y, X<>Y.

% if there is a closeLinkPath from X to Y with shares W1 with a set of visited
% nodes P1, and the node Z is not in the list of the visited nodes, the node Z is
% added in the set of visited nodes, then there is a closeLinkPaths from X,Z
% with visited nodes P
closeLinkPaths(X,Z,J,P) <- closeLinkPaths(X,Y,W1,P1),
                           own(Y,Z,W2),
                           J = W1*W2,
                           P = P1|Z,
                           Z !in P1.

% if there is a closeLinkPaths from the company X to the company Y with shares W
% and the set of visited nodes P, then there is a close_link_sum by grouping by
% X and Y with total share J, by aggregating the sum of W
close_link_sum(X,Y,J) <- closeLinkPaths(X,Y,W,P), J = msum(W).

% if there is a close_link_sum of X over Y with shares W, and the shares is
% greater than 0.2, then the companies X and Y are in close link with shares W
close_link(X,Y,W) <- close_link_sum(X,Y,W), W >= 0.2.
@output("close_link").

% Output of close_link(X,Y,W)
close_link(A, C, 0.24).
close_link(B, D, 0.216).
close_link(D, C, 0.216).
close_link(B, A, 0.908).
close_link(C, D, 0.6).
close_link(A, B, 0.2).
close_link(B, C, 0.36).
close_link(C, A, 0.54).
close_link(D, A, 0.9).